海量的Excel表格，员工基本信息、
提成计算、考勤统计、合同管理
....
没完没了
什么时候才能处理完啊？
不要怕
有小微舞在呢！
在excel中有太多好用的技巧，快来看看哪个最厉害。
想拆分姓名和手机号码？先输入第一个姓名，选取它和下面的空行，按Ctrl+E，一秒搞定拆分（提取手机号码同样方法）
选取两列后，按Ctrl +
复制 - 选择性粘贴 - 跳过空单元。可以跳过空列/行粘贴。
数字长度如果大于11位会以科学记数法显示，设置自定义格式 0 可以让数字正常显示出来。
按CTRL键分两段选取并复制，选取要粘贴的位置，按Enter即完成转换。
不规范的数字和字串，用分列可以快速转换成标准的日期格式。
把列拉宽 - 选取数据 ， 开始 - 填充 - 两端对齐（Excel2003是内容重排）。
按shift选取多个工作表，选取工复制的表格区域，开始 - 填充 - 成组工作表。
Ctrl+g定位空值 - 按alt+=一键设置求和公式。
你以为这就结束了？
赶紧消化上面的内容，
更牛的技能要来了！！！！
员工信息表公式
1、计算性别
(F列)
=IF(MOD(MID(E3,17,1),2),"男","女")
2、出生年月
(G列)
=TEXT(MID(E3,7,8),"0-00-00")
3、年龄公式
(
H
列)
=DATEDIF(G3,TODAY(),"y")
4、退休日期
(
I
列)
=TEXT(EDATE(G3,12*(5*(F3="男")+55)),"yyyy/mm/dd aaaa")
5、籍贯
(
M
列)
=VLOOKUP(LEFT(E3,6)*1,地址库!E:F,2,)
注：附带示例中有地址库代码表
6、社会工龄(T列)
=DATEDIF(S3,NOW(),"y")
7、公司工龄(W列)
=DATEDIF(V3,NOW(),"y")&"年"&DATEDIF(V3,NOW(),"ym")&"月"&DATEDIF(V3,NOW(),"md")&"天"
8、合同续签日期(Y列)
=DATE(YEAR(V3)+LEFTB(X3,2),MONTH(V3),DAY(V3))-1
9、合同到期日期(Z列)
=TEXT(EDATE(V3,LEFTB(X3,2)*12)-TODAY(),"[<0]过期0天;[<30]即将到期0天;还早")
10、工龄工资(AA列)
=MIN(700,DATEDIF($V3,NOW(),"y")*50)
11、生肖
(AB列)
=MID("猴鸡狗猪鼠牛虎兔龙蛇马羊",MOD(MID(E3,7,4),12)+1,1)
员工考勤表公式
1、本月工作日天数
(AG列)
=NETWORKDAYS(B$5,DATE(YEAR(N$4),MONTH(N$4)+1,),)
2、调休天数公式
(AI
列)
=COUNTIF(B9:AE9,"调")
3、扣钱公式
(AO
列)
婚丧扣10块，病假扣20元，事假扣30元，矿工扣50元
=SUM((B9:AE9={"事";"旷";"病";"丧";"婚"})*{30;50;20;10;10})
员工数据分析公式
1、本科学历人数
=COUNTIF(D:D,"本科")
2、办公室本科学历人数
=COUNTIFS(A:A,"办公室",D:D,"本科")
3、30~40岁总人数
=COUNTIFS(F:F,">=30",F:F,"<40")
其他公式
1、
提成比率计算
=VLOOKUP(B3,$C$12:$E$21,3)
2、个人所得税计算
假如A2中是应税工资，则计算个税公式为：
=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)
3、工资条公式
=CHOOSE(MOD(ROW(A3),3)+1,工资数据源!A$1,OFFSET(工资数据源!A$1,INT(ROW(A3)/3),,),"")
注：
4、
Countif函数统计身份证号码出错的解决方法
由于Excel中数字只能识别15位内的，在Countif统计时也只会统计前15位，所以很容易出错。不过只需要用 &"*" 转换为文本型即可正确统计。
=Countif(A:A,A2&"*")
